메소드 정의 및 호출

템플릿 클래스를 복사합니다. 이전 연습문제를 완료한 경우 이 태스크를 건너뛰고 클래스 ZCL_##_LOCAL_CLASS 또는 클래스 ZCL_##_INSTANCES 를 계속 편집할 수 있습니다.

1. ABAP 편집기에서 전역 클래스 /LRN/CL_S4D400_CLS_INSTANCES 의 소스 코드를 엽니다.

   1. Eclipse 툴바에서 Open ABAP Development Object 를 선택합니다. 또는 Ctrl + Shift + A 를 눌러도 됩니다.

   2. 검색 문자열로 /LRN/CL_S4D400_CLS 를 입력합니다.

   3. 개발 오브젝트 리스트에서 /LRN/CL_S4D400_CLS_INSTANCES 를 선택하고 확인 을 선택합니다.

2. 프로젝트 탐색기 뷰를 편집기와 연결합니다.

   1. 프로젝트 탐색기 툴바에서 편집기가 있는 링크 버튼을 찾습니다. 아직 누르지 않은 경우 선택합니다. 따라서 편집기에서 열려 있는 개발 오브젝트가 프로젝트 탐색기에서 강조표시되어야 합니다.

3. /LRN/CL_S4D400_CLS_INSTANCES 클래스를 패키지에 포함된 클래스에 복사합니다(제안 이름: ZCL_##_METHODS, ##은 그룹 번호).

   1. 프로젝트 탐색기 뷰에서 클래스 /LRN/CL_S4D400_CLS_INSTANCES 를 마우스 오른쪽 버튼으로 클릭하여 컨텐트 메뉴를 엽니다.

   2. 단축 메뉴에서 Duplicate .... 를 선택합니다.

   3. 패키지 필드에 패키지 이름을 입력합니다. 이름 필드에 이름 ZCL_##_METHODS 를 입력합니다. 여기서 ##은 그룹 번호입니다.

   4. 내역을 조정하고 다음 을 선택합니다.

   5. 전송 요청을 확인하고 Finish를 선택합니다.

로컬 클래스 lcl_connection 에서 인스턴스 메소드 get_output 과 set_attributes 를 정의합니다.

1. 로컬 클래스 lcl_connection 의 정의로 이동합니다.

   1. 전역 클래스에서 로컬 유형 을 선택합니다.

2. 클래스의 public 섹션에 get_output 메소드를 추가합니다. 글로벌 테이블 유형 STRING_TABLE의 리턴 매개변수 r_output 한 개가 있어야 합니다.

   노트

   리턴 매개변수의 이름은 VALUE( )으로 둘러싸야 합니다.

   1. 코드를 다음과 같이 조정합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      1234567891011121314
      
       PUBLIC SECTION.
      
          DATA carrier_id    TYPE /dmo/carrier_id.
          DATA connection_id TYPE /DMO/Connection_id.
      
          CLASS-DATA conn_counter TYPE i.
      
          METHODS get_output
            returning
              value(r_output) type string_table.
      
        PROTECTED SECTION.
      

      노트

      지금은 "GET_OUTPUT" 메소드에 대한 구현 누락 구문 오류를 무시하십시오.

3. 클래스의 public 섹션에 set_attributes 메소드를 추가합니다. 클래스의 각 인스턴스 특성에 대해 하나의 임포트 매개변수가 있어야 합니다. 특성을 입력할 때 사용한 매개 변수에도 동일한 유형을 사용합니다. 매개변수와 특성을 구분하려면 매개변수 이름에 접두부 i_ 를 추가합니다. 또한 메소드에서 예외 CX_ABAP_INVALID_VALUE가 발생해야 합니다.

   1. 코드를 다음과 같이 조정합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      123456789101112131415161718192021
      
      PUBLIC SECTION.
      
          DATA carrier_id    TYPE /dmo/carrier_id.
          DATA connection_id TYPE /DMO/Connection_id.
      
          CLASS-DATA conn_counter TYPE i.
      
          METHODS set_attributes
            IMPORTING
              i_carrier_id    TYPE /dmo/carrier_id
              i_connection_id TYPE /dmo/connection_id
            RAISING
              cx_abap_invalid_value.
      
          METHODS get_output
            returning
              value(r_output) type string_table.
      
        PROTECTED SECTION.
      

      노트

      지금은 "SET_ATTRIBUTES" 메소드에 대한 구현 누락 구문 오류를 무시하십시오.

1. Quick Fix를 사용하여 클래스에 메소드 구현을 추가합니다.

   1. 편집기에서 메소드 중 하나의 이름에 커서를 놓고 Ctrl + 1 을 누릅니다.

   2. 제안 추가 2개의 구현되지 않은 메소드 를 더블 클릭합니다.

2. get_output 메소드를 구현합니다. 리턴 매개변수 r_output 에 문자열 템플릿을 추가합니다. 문자열 템플릿에서 임베드된 표현식을 사용하여 특성 carrier_id 와 connection_id 의 값을 추가합니다.

   1. 로컬 클래스에서 ENDMETHOD. 문과 METHOD get_output. 사이에 다음 코드를 추가합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      12345
      
           APPEND |------------------------------| TO r_output.
           APPEND |Carrier:     { carrier_id    }| TO r_output.
           APPEND |Connection:  { connection_id }| TO r_output.
      

3. set_attributes 메소드를 구현합니다. 두 임포트 매개변수 중 하나가 비어 있으면(IS INITIAL) CX_ABAP_INVALID_VALUE 예외를 발생시킵니다. 그렇지 않으면 두 개의 인스턴스 특성에 임포트 매개변수 값을 입력합니다.

   1. 코드를 다음과 같이 조정합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      123456789101112
      
      METHOD set_attributes.
      
        IF i_carrier_id IS INITIAL OR i_connection_id IS INITIAL.
          RAISE EXCEPTION TYPE cx_abap_invalid_value.
        ENDIF.
      
        carrier_id    = i_carrier_id. 
        connection_id = i_connection_id.
      
      ENDMETHOD. 
      

4. 클래스를 활성화합니다.

   1. Ctrl + F3 을 선택하여 클래스를 활성화합니다.

전역 클래스의 주요 메소드에서 함수 메소드 get_output 을 호출합니다.

1. 전역 클래스에서 if_oo_adt_classrun~main 메소드의 구현으로 전환합니다.

   1. 전역 클래스에서 전역 클래스 를 선택하고 if_oo_adt_classrun~main 메소드의 구현까지 아래로 스크롤합니다.

2. 메소드 끝에서 참조 변수 연결을 작업 영역으로 사용하여 내부 테이블 연결에 루프를 추가합니다.

   1. ENDMETHOD. 앞에 다음 코드를 추가합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      12345
      
         LOOP AT connections INTO connection.
      
         ENDLOOP.
      

3. 루프에서 각 인스턴스에 대해 함수 메소드 get_output 을 차례로 호출하고 결과를 콘솔에 기록합니다.

   힌트

   메소드 get_output 의 호출을 out->write( ) 의 입력으로 직접 사용할 수 있습니다.

   1. 코드를 다음과 같이 조정합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      1234567
      
        LOOP AT connections INTO connection.
      
           out->write( connection->get_output( ) ).
      
         ENDLOOP.
      

4. 클래스를 활성화합니다. 콘솔 앱으로 실행하고 콘솔 출력을 분석합니다.

   1. Ctrl + F3 을 눌러 클래스를 활성화합니다.

   2. F9 를 눌러 클래스를 실행합니다.

   3. 콘솔 윈도우에서 출력을 분석합니다.

코드 자동 완성을 사용하여 set_attributes 메소드를 호출하고 메소드에서 발생하는 예외를 처리합니다.

1. lcl_connection 클래스의 첫 번째 인스턴스에서 특성 carrier_id 및 connection_id 에 대한 직접 액세스를 인스턴스 메소드 set_attributes( ) 의 호출로 바꿉니다. 코드 자동 완성을 사용하여 메소드의 전체 서명을 삽입합니다.

   힌트

   컴포넌트 선택(->)을 입력한 후 Ctrl + Space 를 눌러 사용 가능한 특성 및 메소드 리스트를 표시합니다. 메소드를 선택한 다음 Shift + Enter를 눌러 메소드의 전체 서명을 삽입합니다.

   1. 첫 번째 connection = NEW #( ). 다음 라인에 커서를 놓습니다.

   2. connection-> 을 입력하고 Ctrl + Space 를 누릅니다.

   3. set_attributes 를 선택하고 Shift + Enter 를 누릅니다.

   4. 임포트 매개변수에 값을 전달합니다. 이 인스턴스의 특성을 설정하는 데 이전에 사용했던 것과 동일한 리터럴을 사용합니다.

   5. 이 인스턴스의 인스턴스 특성에 대한 직접 액세스를 제거하거나 주석을 작성합니다.

2. 예외를 처리합니다. TRY. 및 ENDTRY.을 사용하여 메소드 호출을 둘러싸고 있습니다. CX_ABAP_INVALID_VALUE 예외를 처리하기 위해 CATCH-블록을 추가합니다. 메소드 호출에 성공한 경우에만 신규 인스턴스가 내부 테이블 연결에 추가되어야 합니다.

   1. 생성된 코드 라인 CATCH cx_abap_invalid_value. 의 주석 처리를 해제합니다.

   2. 메소드 호출 앞에 TRY. 를 추가합니다.

   3. ENDTRY. 을 CATCH 문 뒤에 추가합니다.

   4. CATCH 문과 ENDTRY 문 사이에 add out->write( `Method call failed` ).

   5. APPEND 문을 메소드 호출과 CATCH 문 사이를 위로 이동합니다.

   6. 전체 메소드 호출이 다음과 같아야 합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      1234567891011121314151617
      
          TRY.
              connection->set_attributes(
                EXPORTING
                  i_carrier_id    = 'LH'
                  i_connection_id = '0400'
              ).
      
      *       connection->carrier_id    = 'LH'.
      *       connection->connection_id = '0400'. 
      
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      

3. lcl_connection 클래스의 다른 두 인스턴스에 대해 이전 단계를 반복합니다.

   1. 이 단계가 끝나면 if_oo_adt_classrun~main 메소드의 구현이 다음과 유사하게 표시되어야 합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879
      
      METHOD if_oo_adt_classrun~main.
      
          DATA connection TYPE REF TO lcl_connection.
          DATA connections TYPE TABLE OF REF TO lcl_connection.
      
      * First Instance
      **********************************************************************
          connection = NEW #(  ).
      
          TRY.
              connection->set_attributes(
                EXPORTING
                  i_carrier_id    = 'LH'
                  i_connection_id = '0400'
              ).
      
      *        connection->carrier_id    = 'LH'.
      *        connection->connection_id = '0400'.
      
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      
      * Second instance
      **********************************************************************
      
          connection = NEW #(  ).
      
          TRY.
              connection->set_attributes(
                EXPORTING
                  i_carrier_id    = 'AA'
                  i_connection_id = '0017'
              ).
      
      *        connection->carrier_id    = 'AA'.
      *        connection->connection_id = '0017'.
      
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      
      * Third instance
      **********************************************************************
          connection = NEW #(  ).
      
          TRY.
              connection->set_attributes(
                EXPORTING
                  i_carrier_id    = 'SQ'
                  i_connection_id = '0001'
              ).
      
      *        connection->carrier_id    = 'SQ'.
      *        connection->connection_id = '0001'.
      
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      
      
      * Output
      **********************************************************************
      
          LOOP AT connections INTO connection.
      
            out->write( connection->get_output( ) ).
      
          ENDLOOP.
      
        ENDMETHOD.
      

4. 클래스를 활성화합니다. 이를 실행하고 메소드 호출을 디버그합니다.

   1. Ctrl + F3 을 눌러 클래스를 활성화합니다.

   2. F9 를 눌러 클래스를 실행합니다.