기본 기법 및 개념 적용

데이터 처리 중

Objectives

After completing this lesson, you will be able to:
  • 산술 계산을 수행합니다.
  • 문자열 처리를 적용합니다.

산술 계산

산술식은 런타임 시스템에서 결과를 계산하기 위해 처리하는 값, 연산자, 함수의 조합을 갖는 ABAP 식입니다. 산술식의 경우 결과 유형은 표현식에 대한 입력으로 사용되는 피연산자 유형에 따라 달라집니다.

값 지정의 오른쪽 등과 같이 모든 읽기 피연산자 위치에서 산술식을 사용할 수 있습니다.

다음 동영상에서는 산술식의 기본 사항을 보여줍니다.

사용해 보기: 산술 계산

  1. 이 과정의 첫 번째 연습문제와 마찬가지로 인터페이스 IF_OO_ADT_CLASSRUN을 구현하는 신규 전역 클래스를 생성합니다.
  2. 다음 코드 스니핏을 if_oo_adt_classrun~main( ) 메소드의 구현 부분에 복사합니다.
    Code Snippet
    12345678910111213141516171819202122232425262728293031
    
* Declarations
**********************************************************************

    " comment/uncomment these line for different result types
    TYPES t_result TYPE p LENGTH 8 DECIMALS 2.
*    TYPES t_result TYPE p LENGTH 8 DECIMALS 0.
*    TYPES t_result TYPE i.

    DATA result TYPE t_result.

* Calculations
**********************************************************************
    " comment/uncomment these lines for different calculations

    result = 2 + 3.
*    result = 2 - 3.
*    result = 2 * 3.
*    result = 2 / 3.
*
*    result = sqrt( 2 ).
*    result = ipow( base = 2 exp = 3 ).
*
*    result = ( 8 * 7 - 6 ) / ( 5 + 4 ).
*   result = 8 * 7 - 6 / 5 + 4.

* Output
**********************************************************************

    out->write( result ).
  3. CTRL + F3 을 눌러 클래스를 활성화하고 F9 를 눌러 콘솔 앱으로 실행합니다.
  4. 소스 코드를 사용하여 개념을 숙지합니다.
    • 다양한 계산과 유형 정의에 대한 주석 처리를 해제합니다.
    • 계산을 직접 구현합니다.

문자열 처리

문자열 템플릿은 문자열 결과 유형의 ABAP 표현식입니다. 읽기 피연산자 위치(예: 값 지정 오른쪽)에 문자열 템플릿을 사용할 수 있습니다.

문자열 템플릿이 시작되어 파이프 기호( | )로 끝납니다. 가장 간단한 문자열 템플릿에는 리터럴 텍스트만 포함됩니다. 이 서식에서 문자열 템플릿은 문자열 리터럴과 실제로 다르지 않습니다.

문자열 템플릿과 문자열 리터럴을 구분하는 것은 표현식을 임베드하는 기능입니다. 임베드된 표현식은 한 쌍의 중괄호( { 및 } )로 둘러싸인 ABAP 표현식입니다. 런타임 시 ABAP는 임베드된 표현식을 평가하고 결과를 문자열로 변환합니다. 최종 결과에서 이 문자열은 (주변의 중괄호와 함께) 임베드된 표현식을 대체합니다.

노트

ABAP 구문은 여는 대괄호 뒤에 하나 이상의 공백과 닫는 대괄호 앞에 하나 이상의 공백이 필요합니다.

물론 하나의 문자열 템플릿에는 둘 이상의 임베드된 표현식이 포함될 수 있습니다.

중괄호 안에는 위의 예와 같이 모든 종류의 ABAP 표현식을 배치할 수 있지만 단일 변수 또는 리터럴은 임베드된 표현식의 역할을 할 수 있습니다.

문자열 템플릿의 중요한 사용 케이스 중 하나는 출력 데이터의 형식을 제어하는 것입니다.

첫 번째 예에서 변수 the_date 는 d 유형이고 일자는 내부 (원시) 형식 YYYYMMDD (YYYY는 연도, MM 은 월 2자리, DD 는 두 자리 일자) 를 포함합니다. 문자열 템플릿에서 변수 the_date 를 임베드된 표현식으로 사용하면 결과는 내부 형식과 동일합니다. 그러나 중괄호 안에 DATE = <date_format> 형식 옵션을 추가하면 값이 날짜로 지정됩니다. DATE = ISO를 추가하면 ISO 형식으로 출력됩니다. DATE = USER인 경우 출력 형식은 현재 사용자의 사용자 설정에 따라 달라집니다.

두 번째 예는 숫자 서식 지정에 사용할 수 있는 몇 가지 옵션을 보여줍니다. NUMBER를 사용하여 일반적인 숫자 형식을 제어합니다(예: 소수점 사용 여부, 소수점 쉼표). SIGN을 사용하여 부호의 위치와 더하기 기호(+)의 표시 여부를 제어할 수 있습니다. STYLE을 사용하면 과학 스타일 또는 엔지니어링 스타일과 같은 몇 가지 미리 정의된 스타일 중에서 선택할 수 있습니다.

연결 연산자 &&를 사용하여 필드를 서로 조인할 수 있습니다. 데이터 오브젝트와 문자열식의 조합을 조인할 수 있습니다.

표현식의 구성 부분은 공백이나 구분 기호 없이 조인됩니다. 공백 또는 다른 구분 기호 문자가 필요한 경우 두 번째 예제와 같이 이를 표현식의 일부로 직접 삽입해야 합니다.

사용해 보기: 문자열 처리

  1. 이 과정의 첫 번째 연습문제와 마찬가지로 인터페이스 IF_OO_ADT_CLASSRUN을 구현하는 신규 전역 클래스를 생성합니다.
  2. 다음 코드 스니핏을 if_oo_adt_classrun~main( ) 메소드의 구현 부분에 복사합니다.
    Code Snippet
    123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354
    
 METHOD if_oo_adt_classrun~main.

* Declarations
**********************************************************************
    TYPES t_amount TYPE  p LENGTH 8 DECIMALS 2.

    DATA amount   TYPE t_amount VALUE '3.30'.
    DATA amount1  TYPE t_amount VALUE '1.20'.
    DATA amount2  TYPE t_amount VALUE '2.10'.

    DATA the_date  TYPE d                     VALUE '19891109'.
    DATA my_number TYPE p LENGTH 3 DECIMALS 2 VALUE '-273.15'.

    DATA part1 TYPE string VALUE `Hello`.
    DATA part2 TYPE string VALUE `World`.

* String Templates
**********************************************************************

    " comment/uncomment the following lines for different examples
    DATA(text) = |Hello World|.
*    DATA(text) = |Total: { amount } EUR|.
*    DATA(text) = |Total: { amount1 + amount2 } EUR|.

* Format Options
**********************************************************************

    "Date
*    DATA(text) = |Raw Date: { the_date             }|.
*    DATA(text) = |ISO Date: { the_date Date = ISO  }|.
*    DATA(text) = |USER Date:{ the_date Date = USER }|.

    "Number
*    DATA(text) = |Raw Number { my_number                    }|.
*    DATA(text) = |User Format{ my_number NUMBER = USER      }|.
*    DATA(text) = |Sign Right { my_number SIGN = RIGHT       }|.
*    DATA(text) = |Scientific { my_number STYLE = SCIENTIFIC }|.

* String expression (concatenation Operator)
**********************************************************************

*    DATA(text) = part1 && part2.
*    DATA(text) = part1 && | | && part2.
*    DATA(text) = |{ amount1 } + { amount2 }| &&
*                 | = | &&
*                 |{ amount1 + amount2 }|.


* Output
**********************************************************************

    out->write( text ).
  3. CTRL + F3 을 눌러 클래스를 활성화하고 F9 를 눌러 콘솔 앱으로 실행합니다.
  4. 소스 코드를 사용하여 개념을 숙지합니다.
    • 다른 결과를 보려면 인라인 선언 변수 텍스트에 대한 다른 값 지정의 주석을 해제하십시오.
    • 자신의 지정사항을 시도해 보십시오.

변수 선언 및 데이터 처리

이번 연습문제에서는 두 숫자를 기준으로 계산을 수행한 다음 결과를 출력하고 서식을 지정하는 프로그램을 생성합니다.

템플릿:

  • 없음

솔루션:

  • /LRN/CL_S4D400_BTS_COMPUTE(전역 클래스)

태스크 1: 변수 선언

자체 패키지에서 신규 전역 클래스를 생성하고 입력을 위한 숫자 변수를 정의합니다.

단계

  1. IF_OO_ADT_CLASSRUN 인터페이스를 구현하는 신규 전역 클래스를 생성합니다(제안 이름: ZCL_##_COMPUTE, ##은 그룹 번호).

    1. 파일→신규→ABAP 클래스 를 선택합니다.

    2. 패키지 필드에 패키지 이름을 입력합니다. 이름 필드에 이름 ZCL_##_COMPUTE 를 입력합니다. 여기서 ##은 그룹 번호입니다.

    3. 내역을 입력하십시오.

    4. 인터페이스 그룹 상자에서 추가 를 선택합니다.

    5. IF_OO_ADT_CLASSRUN 을 입력합니다. 인터페이스가 적중 리스트에 표시되면 더블 클릭하여 클래스 정의에 추가합니다.

    6. 다음을 선택합니다.

    7. 전송 요청을 선택하고 Finish 를 선택합니다.

  2. IF_OO_ADT_CLASSRUN~MAIN 메소드에서 정수 값에 대한 두 개의 변수(제안 이름: number1 및 number2)를 선언합니다.

    1. 다음 코드를 추가합니다.

      Code Snippet
      1234
      
    DATA number1 TYPE i.
    DATA number2 TYPE i.

  3. 두 숫자 변수 각각에 대한 값 지정을 구현합니다. 첫 번째 변수에는 음수 값을, 두 번째 변수에는 양수 값을 지정합니다.

    1. 다음 코드를 추가합니다.

      Code Snippet
      1234
      
    number1 = -8.
    number2 =  3.

태스크 2: 데이터 처리

비율을 계산하고 콘솔에 결과를 기록합니다.

단계

  1. 두 숫자의 비율을 계산하는 산술식을 구현합니다. 인라인 선언을 사용하여 선언하는 변수에 결과를 저장합니다(제안 이름: 결과).

    1. 다음 코드를 추가합니다.

      Code Snippet
      123
      
    DATA(result) = number1 / number2.

  2. 6, 3, 2 대신 변수의 실제 값과 함께:"6 / 3 = 2" 와 같은 텍스트를 포함하는 문자열 템플릿을 구현합니다. 인라인 선언을 사용하여 선언하는 변수에 결과를 저장합니다(제안 이름: 출력).

    1. 다음 코드를 추가합니다.

      Code Snippet
      123
      
    DATA(output) = |{ number1 } / { number2 } = { result }|.

  3. out->write( … ) 메소드를 호출하여 텍스트를 콘솔에 작성합니다.

    1. 이전 연습문제에서 수행한 대로 진행합니다.

태스크 3: 활성화 및 테스트

콘솔 앱을 활성화하고 테스트합니다.

단계

  1. 클래스를 활성화합니다.

    1. Ctrl + F3 을 눌러 클래스를 활성화합니다.

  2. 콘솔 앱을 실행합니다.

    1. F9 를 눌러 콘솔 앱을 실행합니다.

  3. 다양한 입력 값으로 앱을 테스트합니다.

    1. 값 지정을 편집한 후 이전과 같이 활성화하고 실행합니다.

태스크 4: 결과 정밀도 제어

결과가 정수 값이 아닌 소수점 이하 2자리의 값으로 반올림되어야 합니다.

단계

  1. 인라인 선언 대신 변수 결과의 명시적 선언을 사용합니다. 소수 자릿수를 지정할 수 있는 숫자 유형을 사용합니다.

    1. if_oo_adt_classrun~main 메소드 시작 부분에 다음 코드를 추가합니다.

      Code Snippet
      123
      
    DATA result TYPE p LENGTH 8 DECIMALS 2.

    2. 인라인 선언이 있는 코드 라인에서 DATA(result) 을 result 으로 바꿉니다.

  2. 클래스를 활성화하고 다시 테스트합니다.

    1. 앞에서 수행한 대로 진행합니다.

    2. 코드를 모델 솔루션에서 추출한 다음 과 비교합니다.

      Code Snippet
      12345678910111213141516171819202122232425262728293031323334
      
 METHOD if_oo_adt_classrun~main.

* Declarations
**************************

    DATA number1 TYPE i.
    DATA number2 TYPE i.

    DATA result TYPE p LENGTH 8 DECIMALS 2.

    
* Input Values
**************************

    number1 = -8.
    number2 =  3.

* Calculation
**************************

*    DATA(result) = number1 / number2.   "with inline declaration 
 
   result = number1 / number2.

    DATA(output) = |{ number1 } / { number2 } = { result }|.

* Output
**************************

    out->write( output ).

  ENDMETHOD.
Learning

SAP FacebookSAP YoutubeSAP LinkedIn