캡슐화를 사용하여 일관성 보장

템플릿 클래스를 복사합니다. 이전 연습문제를 완료한 경우 이 태스크를 건너뛰고 클래스(ZCL_##_METHODS, ZCL_##_LOCAL_CLASS 또는 ZCL_##_INSTANCES)를 계속 편집할 수 있습니다.

1. 클래스 /LRN/CL_S4D400_CLS_METHODS 를 자체 패키지의 클래스에 복사합니다(제안 이름: ZCL_##_CONSTRUCTOR, ##은 그룹 번호).

   1. 전역 클래스 /LRN/CL_S4D400_CLS_METHODS의 소스 코드를 엽니다.

   2. 프로젝트 탐색기 뷰를 편집기와 연결합니다.

   3. 프로젝트 탐색기 뷰에서 /LRN/CL_S4D400_CLS_METHODS 클래스를 마우스 오른쪽 버튼으로 클릭하여 단축 메뉴를 엽니다.

   4. 단축 메뉴에서 Duplicate .... 를 선택합니다.

   5. 패키지 필드에 패키지 이름을 입력합니다. 이름 필드에 이름 ZCL_##_CONSTRUCTOR 를 입력합니다. 여기서 ##은 그룹 번호입니다.

   6. 내역을 조정하고 다음 을 선택합니다.

   7. 전송 요청을 확인하고 Finish를 선택합니다.

set_attributes( ) 및 get_output( ) 메소드를 사용하도록 특성 carrier_id 와 connection_id 의 표시 여부를 변경합니다.

1. Quick Fix를 사용하여 특성 carrier_id의 표시 여부를 private으로 설정합니다.

   1. 로컬 유형 탭으로 전환합니다.

   2. 로컬 클래스 lcl_connection 의 carrier_id 특성의 선언으로 이동합니다.

   3. carrier_id 에 커서를 놓고 Ctrl + 1 을 누릅니다.

   4. 제안인 carrier_id를 비공개로 설정 을 더블 클릭합니다.

   5. carrier_id 특성의 선언이 private 섹션으로 이동했는지 확인합니다.

2. Quick Fix를 사용하여 connection_id 특성의 표시 여부를 private 으로 설정합니다.

   1. 로컬 클래스 lcl_connection 의 connection_id 특성의 선언으로 이동합니다.

   2. connection_id 에 커서를 놓고 Ctrl + 1 을 누릅니다.

   3. 제안 make connection_id private 을 더블 클릭합니다.

   4. connection_id 특성의 선언이 private 섹션으로 이동했는지 확인합니다.

public 메소드 set_attributes를 인스턴스 생성자로 대체하여 신규 인스턴스를 생성하는 동안 특성이 설정되고 나중에 변경되지 않도록 합니다.

1. set_attributes 메소드의 정의와 구현을 주석 처리합니다.

   1. 기간 기호(.)가 있는 라인을 포함하여 METHODS set_attributes 문에 속하는 모든 라인을 선택합니다.

   2. Ctrl + < 를 눌러 선택한 각 라인 앞에 별표 기호(*)를 추가합니다.

   3. 해당 ENDMETHOD. 문을 포함하여 set_attributes 메소드 구현에 속하는 라인을 모두 선택하고 Ctrl + < 를 다시 누릅니다.

2. Quick Fix를 사용하여 로컬 클래스 lcl_connection 에 인스턴스 생성자를 추가합니다. 생성자에 특성 carrier_id 및 connection_id 에 해당하는 임포트 매개변수가 있는지 확인합니다.

   1. 클래스 이름에 커서를 놓고 Ctrl + 1 을 누릅니다.

   2. 생성자 생성 을 더블 클릭합니다.

   3. 대화 상자에서 carrier_id 와 connection_id 가 선택되었는지 확인하고 Finish 를 선택합니다.

3. 생성된 생성자 정의를 확장합니다. 메소드 생성자의 정의에 CX_ABAP_INVALID_VALUE 예외를 추가합니다.

   1. 생성된 메소드 생성자 정의로 이동합니다.

   2. 코드를 다음과 같이 조정합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      12345678
      
      METHODS constructor
            IMPORTING
              i_connection_id TYPE /dmo/connection_id
              i_carrier_id    TYPE /dmo/carrier_id
            RAISING
              cx_ABAP_INVALID_VALUE.
      

4. 생성된 생성자 구현을 확장합니다. 임포트 매개변수 중 하나가 초기 값이면 예외 CX_ABAP_INVALID_VALUE를 발생시킵니다.

   1. 정의에서 메소드 생성자 구현으로 이동합니다(예: 생성자에 커서를 놓고 F3 누르기).

   2. 코드를 다음과 같이 조정합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      123456789101112
      
      METHOD constructor.
       
          IF i_carrier_id IS INITIAL OR i_connection_id IS INITIAL.
            RAISE EXCEPTION TYPE cx_abap_invalid_value.
          ENDIF.
      
          me->connection_id = i_connection_id.
          me->carrier_id    = i_carrier_id.
      
        ENDMETHOD.
      

5. 생성자 구현에서 문을 추가하여 정적 특성 conn_counter 의 값을 하나씩 늘립니다. 예외가 발생하지 않은 경우에만 명령문이 실행되어야 합니다.

   1. 코드를 다음과 같이 조정합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      12345678
      
          me->connection_id = i_connection_id.
          me->carrier_id    = i_carrier_id.
         
          conn_counter = conn_counter + 1.
      
        ENDMETHOD.
      

6. 클래스 외부에서 conn_counter 의 값을 변경할 수 없는지 확인하십시오.

   1. 정적 특성 conn_counter 의 선언에 READ-ONLY 를 추가합니다.

   2. 코드를 다음과 같이 조정합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      123
      
         CLASS-DATA conn_counter TYPE i READ-ONLY.
      

lcl_connection 클래스의 인스턴스화를 조정하여 인스턴스 생성자의 매개변수를 제공하고 예외를 처리합니다.

1. if_oo_adt_classrun~main 메소드에서 lcl_connection의 첫 번째 인스턴스에 대한 NEW #( ) 표현식으로 이동합니다.

   1. 전역 클래스 탭으로 전환합니다.

   2. connection = NEW #( ). 을 사용하여 첫 번째 라인을 찾습니다.

2. NEW 표현식에서 생성자의 임포트 매개변수를 제공합니다.

   힌트

   이 인스턴스의 set_attributes 메소드 호출에서 전달하는 매개변수를 복사할 수 있습니다.

   1. NEW 표현식을 다음과 같이 조정합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      123456
      
         connection = NEW #( 
                             i_carrier_id    = 'LH'
                             i_connection_id = '0400' 
                           ).
      

3. set_attributes 메소드의 모든 호출을 제거하거나 주석 처리합니다.

   1. 닫는 괄호와 마침표(.)가 있는 라인을 포함하여 connection->set_attributes( ... ). 문에 속하는 모든 라인을 선택합니다.

   2. Ctrl + < 를 눌러 선택한 각 라인 앞에 별표 기호(*)를 추가합니다.

4. 인스턴스 생성을 예외 처리의 TRY 블록으로 이동합니다.

   1. TRY. 문을 인스턴스 생성 전으로 위로 이동합니다.

   2. 첫 번째 인스턴스 생성은 다음과 같아야 합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      12345678910111213141516171819
      
      TRY.
          connection = NEW #( 
                              i_carrier_id    = 'LH'
                              i_connection_id = '0400'
                            ).
         
      *        connection->set_attributes(
      *          EXPORTING
      *            i_carrier_id    = 'LH'
      *            i_connection_id = '0400'
      *        ).
      
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      

5. 로컬 클래스의 다른 인스턴스에 대해 이전 단계를 반복합니다.

   1. 이 단계가 끝나면 if_oo_adt_classrun~main 메소드의 구현이 다음과 유사하게 표시되어야 합니다.

      Code Snippet

      Copy codeSwitch to dark mode

      1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859
      
      METHOD if_oo_adt_classrun~main.
      
          DATA connection TYPE REF TO lcl_connection.
          DATA connections TYPE TABLE OF REF TO lcl_connection.
      
      * First Instance
      **********************************************************************
          TRY.
          connection = NEW #( 
                              i_carrier_id    = 'LH'
                              i_connection_id = '0400'
                            ).
         
      *        connection->set_attributes(
      *          EXPORTING
      *            i_carrier_id    = 'LH'
      *            i_connection_id = '0400'
      *        ).
      
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      
      * Second instance
      **********************************************************************
          TRY.
          connection = NEW #(  
                              i_carrier_id    = 'AA'
                              i_connection_id = '0017'
                            ).
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      
      * Third instance
      **********************************************************************
          TRY.
          connection = NEW #(  
                              i_carrier_id    = 'SQ'
                              i_connection_id = '0001'
                            ).
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      
      * Output
      **********************************************************************
          LOOP AT connections INTO connection.
            out->write( connection->get_output( ) ).
          ENDLOOP.
        ENDMETHOD.
      

6. 클래스를 활성화합니다. 이를 실행하고 인스턴스화를 디버그합니다.

   1. Ctrl + F3 을 눌러 클래스를 활성화합니다.

   2. F9 를 눌러 클래스를 실행합니다.