Mit einfachen internen Tabellen arbeiten

Legen Sie in Ihrem eigenen Paket eine neue globale Klasse an. Definieren Sie eine Konstante für die Anzahl der Iterationen und eine interne Tabelle für die Fibonacci-Zahlen. Berechnen Sie dann die Fibonacci-Zahlen in einer Iteration, und speichern Sie sie in der internen Tabelle.

1. Legen Sie eine neue globale Klasse an, die das Interface IF_OO_ADT_CLASSRUN implementiert (Namensvorschlag: ZCL_##_ITERATE, wobei ## für Ihre Gruppennummer steht).

   1. Wählen Sie File→New→ABAP Class.

   2. Geben Sie den Namen Ihres Pakets in das Feld Package ein. Geben Sie im Feld Name den Namen ZCL_##_ITERATE ein, wobei ## für Ihre Gruppennummer steht.

   3. Geben Sie eine Beschreibung ein.

   4. Wählen Sie im Gruppenrahmen Interfaces die Option Add.

   5. Geben Sie IF_OO_ADT_CLASSRUN ein. Wenn das Interface in der Trefferliste angezeigt wird, fügen Sie es mit Doppelklick zur Klassendefinition hinzu.

   6. Wählen Sie Next.

   7. Wählen Sie Ihren Transportauftrag aus, und wählen Sie Finish.

2. Definieren Sie in der Methode IF_OO_ADT_CLASSRUN~MAIN eine Konstante für die Anzahl der Iterationen (Namensvorschlag: max_count) mit einem kleinen Wert, z.B. 20.

   1. Fügen Sie folgenden Code hinzu:

      Code Snippet

      Copy codeSwitch to dark mode

      123
      
         CONSTANTS max_count TYPE i VALUE 20.
      

3. Deklarieren Sie eine einfache interne Tabelle zum Speichern der Fibonacci-Nummern (Namensvorschlag: Zahlen).

   1. Fügen Sie folgenden Code hinzu:

      Code Snippet

      Copy codeSwitch to dark mode

      123
      
        DATA numbers TYPE TABLE OF i.
      

4. Implementieren Sie eine Iteration, die max_count mal ausgeführt wird.

   1. Fügen Sie nach den Deklarationen den folgenden Quelltext hinzu:

      Code Snippet

      Copy codeSwitch to dark mode

      12345
      
        DO max_count TIMES.
      
        ENDDO.
      

5. Implementieren Sie innerhalb der Iteration eine Fallunterscheidung basierend auf dem eingebauten Iterationszähler: In der ersten Iteration fügen Sie der internen Tabelle numbers den Wert 0 hinzu. Fügen Sie in der zweiten Iteration den Wert 1 am Ende der internen Tabelle numbers hinzu.

   Hinweis

   Der eingebaute Iterationszähler ist das Systemfeld sy-index.

   1. Fügen Sie zwischen DO und ENDDO folgenden Code hinzu:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678
      
         CASE sy-index.
            WHEN 1.
              APPEND 0 TO numbers.
            WHEN 2.
              APPEND 1 TO numbers.
         ENDCASE.
      

6. Fügen Sie eine Verzweigung hinzu, die für alle anderen Werte ausgeführt wird. Berechnen Sie in dieser Verzweigung den neuen Eintrag als Summe der beiden vorherigen Einträge in numbers.

   Hinweis

   Greifen Sie über den Index sy-index - 1 und sy-index - 2 auf die vorherigen Einträge zu.

   1. Passen Sie den Quelltext wie folgt an:

      Code Snippet

      Copy codeSwitch to dark mode

      123456789101112
      
         CASE sy-index.
            WHEN 1.
              APPEND 0 TO numbers.
            WHEN 2.
              APPEND 1 TO numbers.
            WHEN OTHERS.
                APPEND numbers[  sy-index - 2 ]
                     + numbers[  sy-index - 1 ]
                    TO numbers.
         ENDCASE.
      

Bereiten Sie in einer Schleife über der internen Tabelle eine formatierte Ausgabe vor, in der jede Fibonacci-Zahl mit der jeweiligen Folgenummer aufgeführt ist. Bereiten Sie die Ausgabe in einer anderen internen Tabelle mit dem Zeilentyp string vor.

1. Deklarieren Sie am Anfang der Methode if_oo_adt_classrun~main eine interne Tabelle vom Zeilentyp string (Namensvorschlag: output).

2. Implementieren Sie eine Schleife über die interne Tabelle numbers, um die Fibonacci-Zahlen nacheinander in eine Variable number zu lesen.

   Hinweis

   Verwenden Sie eine Inline-Deklaration für number.

   1. Fügen Sie am Ende der Methode den folgenden Code hinzu:

      Code Snippet

      Copy codeSwitch to dark mode

      12345
      
        LOOP AT numbers INTO DATA(number).
      
        ENDLOOP.
      

3. Deklarieren Sie eine Ganzzahlvariable (vorgeschlagener Name: counter), die Sie vor der Schleife auf null setzen und in jeder Iteration um 1 erhöhen.

   Hinweis

   Sie können eine Inline-Deklaration für counter verwenden.

   1. Passen Sie den Quelltext wie folgt an:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678
      
        DATA(counter) = 0.
        LOOP AT numbers INTO DATA(number).
      
           counter = counter + 1.
      
        ENDLOOP.
      

4. Fügen Sie in jeder Iteration der internen Tabelle output eine neue Zeile hinzu, die den Inhalt von counter (4 Zeichen breit, linksbündig), einen Doppelpunkt (:) und den Inhalt von number (10 Zeichen breit, rechtsbündig) enthält.

   Hinweis

   Verwenden Sie ein Zeichenketten-Template mit geeigneten Formatoptionen, um das Format anzupassen.

   1. Passen Sie den Quelltext wie folgt an:

      Code Snippet

      Copy codeSwitch to dark mode

      1234567891011
      
        DATA(counter) = 0.
        LOOP AT numbers INTO DATA(number).
      
           counter = counter + 1.
      
           APPEND |{ counter WIDTH = 4 ALIGN = LEFT }: { number WIDTH = 10 ALIGN = RIGHT }|
               TO output.
      
        ENDLOOP.
      

Schreiben Sie das Ergebnis in die Konsole. Anschließend aktivieren und testen Sie Ihre Klasse als Konsolen-App.

1. Rufen Sie am Ende der Methode die Methode out->write auf, um den Inhalt von output in die Konsole zu schreiben. Geben Sie dem Importing-Parameter name eine geeignete Beschriftung.

   1. Fügen Sie nach ENDLOOP. den folgenden Code hinzu:

      Code Snippet

      Copy codeSwitch to dark mode

      123456
      
        out->write( 
               data   = output
               name   = |The first { max_count } Fibonacci Numbers|
                      ) .
      

2. Aktivieren Sie die Klasse.

   1. Drücken Sie Strg + F3, um die Klasse zu aktivieren.

3. Führen Sie Ihre Klasse als Konsolen-App aus.

   1. Drücken Sie F9, um die Klasse als Konsolen-App auszuführen.