Definición y llamada de métodos

Copie la clase de modelo. Si ha finalizado el ejercicio anterior, puede omitir esta tarea y continuar editando su clase ZCL_##_LOCAL_CLASS o su clase ZCL_##_INSTANCES.

1. Abra el código fuente de la clase global /LRN/CL_S4D400_CLS_INSTANCES en el editor ABAP.

   1. En la barra de herramientas de Eclipse, seleccione Abrir objeto de desarrollo ABAP. Como alternativa, pulse Ctrl + Mayús + A.

   2. Introduzca /LRN/CL_S4D400_CLS como string de búsqueda.

   3. En la lista de objetos de desarrollo, seleccione /LRN/CL_S4D400_CLS_INSTANCES y, a continuación, seleccione OK.

2. Vincule la vista Explorador de proyectos con el editor.

   1. En la barra de herramientas Explorador de proyectos, busque el botón Vincular con editor. Si aún no se ha pulsado, selecciónelo. Como resultado, el objeto de desarrollo, que está abierto en el editor, debería resaltarse en el Explorador de proyectos.

3. Copie la clase /LRN/CL_S4D400_CLS_INSTANCES en una clase de su propio paquete (nombre sugerido: ZCL_##_METHODS, donde ## representa su número de grupo).

   1. En la vista Explorador de proyectos, haga clic con el botón derecho en la clase /LRN/CL_S4D400_CLS_INSTANCES para abrir el menú de contenido.

   2. En el menú contextual, seleccione Duplicar ....

   3. Introduzca el nombre del paquete en el campo Paquete. En el campo Nombre, introduzca el nombre ZCL_##_METHODS, donde ## representa su número de grupo.

   4. Ajuste la descripción y seleccione Siguiente.

   5. Confirme la orden de transporte y seleccione Finalizar.

En su clase local lcl_connection, defina los métodos de instancia get_output y set_attributes.

1. Navegue a la definición de la clase local lcl_connection.

   1. En la clase global, seleccione Tipos locales.

2. Añada un método get_output a la sección pública de la clase. Debería tener un parámetro de retorno r_output del tipo de tabla global STRING_TABLE.

   Nota

   Recuerde rodear el nombre del parámetro de retorno con VALUE( ).

   1. Ajuste el código de la siguiente manera:

      Code Snippet

      Copy codeSwitch to dark mode

      1234567891011121314
      
       PUBLIC SECTION.
      
          DATA carrier_id    TYPE /dmo/carrier_id.
          DATA connection_id TYPE /DMO/Connection_id.
      
          CLASS-DATA conn_counter TYPE i.
      
          METHODS get_output
            returning
              value(r_output) type string_table.
      
        PROTECTED SECTION.
      

      Nota

      Por el momento, ignore el error de sintaxis Falta implementación para el método "GET_OUTPUT".

3. Añada un método set_attributes a la sección pública de la clase. Debería tener un parámetro de importación para cada atributo de instancia de la clase. Utilice los mismos tipos para los parámetros que ha utilizado para tipificar los atributos. Para distinguir los parámetros de los atributos, añada el prefijo i_ a los nombres de parámetro. Además, el método debe emitir la excepción CX_ABAP_INVALID_VALUE.

   1. Ajuste el código de la siguiente manera:

      Code Snippet

      Copy codeSwitch to dark mode

      123456789101112131415161718192021
      
      PUBLIC SECTION.
      
          DATA carrier_id    TYPE /dmo/carrier_id.
          DATA connection_id TYPE /DMO/Connection_id.
      
          CLASS-DATA conn_counter TYPE i.
      
          METHODS set_attributes
            IMPORTING
              i_carrier_id    TYPE /dmo/carrier_id
              i_connection_id TYPE /dmo/connection_id
            RAISING
              cx_abap_invalid_value.
      
          METHODS get_output
            returning
              value(r_output) type string_table.
      
        PROTECTED SECTION.
      

      Nota

      Por el momento, ignore el error de sintaxis Falta implementación para el método "SET_ATTRIBUTES".

1. Utilice una corrección rápida para añadir las implementaciones de método a la clase.

   1. Sitúe el cursor en el nombre de uno de los métodos en el editor y pulse Ctrl + 1.

   2. Haga doble clic en la sugerencia Añadir 2 métodos no implementados.

2. Implemente el método get_output. Añada algunos modelos de cadena para devolver el parámetro r_output. En los modelos de cadena, utilice expresiones integradas para añadir los valores de los atributos carrier_id y connection_id.

   1. En la clase local, añada el siguiente código entre las sentencias METHOD get_output. y ENDMETHOD.

      Code Snippet

      Copy codeSwitch to dark mode

      12345
      
           APPEND |------------------------------| TO r_output.
           APPEND |Carrier:     { carrier_id    }| TO r_output.
           APPEND |Connection:  { connection_id }| TO r_output.
      

3. Implemente el método set_attributes. Si alguno de los dos parámetros de importación está vacío (IS INITIAL), emita la excepción CX_ABAP_INVALID_VALUE. De lo contrario, rellene los dos atributos de instancia con los valores de los parámetros de importación.

   1. Ajuste el código de la siguiente manera:

      Code Snippet

      Copy codeSwitch to dark mode

      123456789101112
      
      METHOD set_attributes.
      
        IF i_carrier_id IS INITIAL OR i_connection_id IS INITIAL.
          RAISE EXCEPTION TYPE cx_abap_invalid_value.
        ENDIF.
      
        carrier_id    = i_carrier_id. 
        connection_id = i_connection_id.
      
      ENDMETHOD. 
      

4. Active su clase.

   1. Seleccione Ctrl + F3 para activar la clase.

En el método principal de su clase global, llame el método funcional get_output.

1. Cambie a la implementación del método if_oo_adt_classrun~main en la clase global.

   1. En la clase global, seleccione Clase global, desplácese hacia abajo hasta la implementación del método if_oo_adt_classrun~main.

2. Al final del método, añada un loop sobre las conexiones de tabla internas con una conexión de variable de referencia como área de trabajo.

   1. Añada el siguiente código antes de ENDMETHOD..

      Code Snippet

      Copy codeSwitch to dark mode

      12345
      
         LOOP AT connections INTO connection.
      
         ENDLOOP.
      

3. En el loop, llame el método funcional get_output para cada instancia a su vez y escriba el resultado en la consola.

   Consejo

   Puede utilizar la llamada del método get_output directamente como entrada para out->write( ).

   1. Ajuste el código de la siguiente manera:

      Code Snippet

      Copy codeSwitch to dark mode

      1234567
      
        LOOP AT connections INTO connection.
      
           out->write( connection->get_output( ) ).
      
         ENDLOOP.
      

4. Active la clase. Ejecútela como una aplicación de consola y analice la salida de la consola.

   1. Pulse Ctrl + F3 para activar la clase.

   2. Pulse F9 para ejecutar la clase.

   3. Analice la salida en la ventana Consola.

Utilice la compleción de código para llamar el método set_attributes y tratar la excepción que emite el método.

1. Para la primera instancia de la clase lcl_connection, sustituya el acceso directo a los atributos carrier_id y connection_id por una llamada del método de instancia set_attributes( ). Utilice la compleción de código para insertar la firma completa del método.

   Consejo

   Pulse Ctrl + Espacio después de escribir el componente select (->) para visualizar una lista de atributos y métodos disponibles. Seleccione el método y, a continuación, pulse Mayús + Intro para insertar la firma completa del método.

   1. Coloque el cursor en la siguiente línea después de la primera connection = NEW #( )..

   2. Escriba connection-> y pulse Ctrl + Espacio.

   3. Seleccione set_attributes y pulse Mayús + Intro.

   4. Transfiera valores a los parámetros de importación. Utilice los mismos literales que ha utilizado anteriormente para fijar los atributos de esta instancia.

   5. Elimine o comente el acceso directo a los atributos de instancia para esta instancia.

2. Trate la excepción. Rodee la llamada de método con TRY. y ENDTRY.. Añada un bloque CATCH para tratar la excepción CX_ABAP_INVALID_VALUE. Asegúrese de que la nueva instancia solo se añada a las conexiones de tabla internas si la llamada de método se ha realizado correctamente.

   1. Anule el comentario de la línea de código generada CATCH cx_abap_invalid_value..

   2. Añada TRY. antes de la llamada de método.

   3. Añada ENDTRY. después de la sentencia CATCH.

   4. Entre la sentencia CATCH y la sentencia ENDTRY agregue out->write( `Method call failed` ).

   5. Mueva la sentencia APPEND hacia arriba entre la llamada de método y la sentencia CATCH.

   6. La llamada de método completa ahora debería tener el siguiente aspecto:

      Code Snippet

      Copy codeSwitch to dark mode

      1234567891011121314151617
      
          TRY.
              connection->set_attributes(
                EXPORTING
                  i_carrier_id    = 'LH'
                  i_connection_id = '0400'
              ).
      
      *       connection->carrier_id    = 'LH'.
      *       connection->connection_id = '0400'. 
      
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      

3. Repita el paso anterior para las otras dos instancias de la clase lcl_connection.

   1. Después de este paso, la implementación del método if_oo_adt_classrun~main debería tener un aspecto similar al siguiente:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879
      
      METHOD if_oo_adt_classrun~main.
      
          DATA connection TYPE REF TO lcl_connection.
          DATA connections TYPE TABLE OF REF TO lcl_connection.
      
      * First Instance
      **********************************************************************
          connection = NEW #(  ).
      
          TRY.
              connection->set_attributes(
                EXPORTING
                  i_carrier_id    = 'LH'
                  i_connection_id = '0400'
              ).
      
      *        connection->carrier_id    = 'LH'.
      *        connection->connection_id = '0400'.
      
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      
      * Second instance
      **********************************************************************
      
          connection = NEW #(  ).
      
          TRY.
              connection->set_attributes(
                EXPORTING
                  i_carrier_id    = 'AA'
                  i_connection_id = '0017'
              ).
      
      *        connection->carrier_id    = 'AA'.
      *        connection->connection_id = '0017'.
      
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      
      * Third instance
      **********************************************************************
          connection = NEW #(  ).
      
          TRY.
              connection->set_attributes(
                EXPORTING
                  i_carrier_id    = 'SQ'
                  i_connection_id = '0001'
              ).
      
      *        connection->carrier_id    = 'SQ'.
      *        connection->connection_id = '0001'.
      
              APPEND connection TO connections.
      
            CATCH cx_abap_invalid_value.
              out->write( `Method call failed` ).
          ENDTRY.
      
      
      * Output
      **********************************************************************
      
          LOOP AT connections INTO connection.
      
            out->write( connection->get_output( ) ).
      
          ENDLOOP.
      
        ENDMETHOD.
      

4. Active la clase. Ejecútelo y depure las llamadas de método.

   1. Pulse Ctrl + F3 para activar la clase.

   2. Pulse F9 para ejecutar la clase.