Defining Determine Actions and Side Effect

In your business object, define a determine action (suggested name: checkCustomer) to trigger the validation of the customer ID. Expose the determine action to the OData UI service and define a side effect to execute the determine action when the user changes the customer ID.

1. Edit the behavior definition on data model level Z##_R_TRAVEL. After the validations and determination definition, define a determine action (suggested name: checkCustomer) that triggers the validation of the customer ID.

   1. After the definition of the validations and the determination, add the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      1234
      determine action checkCustomer
      {
        validation validateCustomer;
      }

2. Activate the behavior definition.

   1. Press Ctrl + F3 to activate the development object.

3. Edit the behavior definition on projection level Z##_C_TRAVEL and add the determine action to the projection.

   1. Add the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      1
      use action checkCustomer;

4. After the projection of the determine action, define a side effect that triggers the determine action.

   1. Add the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      12345
      side effects
      {
        determine action checkCustomer
      
      }

5. Use changes to the CustomerId field as the side effect trigger.

   1. Adjust your code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      123456
      side effects
      {
        determine action checkCustomer
        executed on field CustomerId
      
      }

6. Specify the messages as the side effect target that the UI might have to reload after the execution of the side effect.

   1. Adjust your code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      123456
      side effects
      {
        determine action checkCustomer
        executed on field CustomerId
        affects messages;   
      }

7. Activate the behavior definition.

   1. Press Ctrl + F3 to activate the development object.

8. Restart the OData UI service preview and verify that the determine action is executed after you edit the Customer ID.

   1. Open the service binding, place the cursor on the root entity, and choose Preview....

   2. In the preview, display the details for one of the travels. Change to edit mode and delete the value in the Customer ID field.

   3. Press Tab to save the draft and jump to the next input field.

      Result

      You immediately see the error message from the validation.

Extend the root entity of your business object with a view element for the duration of the travel in days (suggested name: Duration). Use the dats_days_between SQL function to calculate this information based on the persistent values of begin_date and end_date.

Expose the new view element to your OData UI service and add it to the list page and the object page. Then set it to read-only.

1. Edit the CDS view entity on data model level Z##_R_Travel. Insert a new row before the Status view element, and use code completion to insert a call of SQL function dats_days_between.

   1. In the element list of the view definition, insert a new row above the Status view element.

   2. Enter dats and press Ctrl + Space to invoke code completion.

   3. From the suggestion list, choose dats_days_between( date1, date2 ) (function).

2. Supply the function with the table fields begin_date and end_date and define a name for the new view element (suggested name: Duration) .

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      12345
      end_date                                  as EndDate,
      
      dats_days_between( begin_date, end_date ) as Duration,
             
      status                                    as Status,

3. Activate the data definition.

   1. Press Ctrl + F3 to activate the development object.

4. Now edit the projection view Z##_C_Travel. Add the new view element and annotate this element with a suitable label, for example, Duration (days).

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      123456
      EndDate,
      
      @EndUserText.label: 'Duration (days)'
      Duration,
      
      Status,

5. Activate the data definition.

   1. Press Ctrl + F3 to activate the development object.

6. Now edit the metadata extension Z##_C_TRAVEL and add @UI.lineItem and @UI.identification annotations for the new view element.

   1. Add the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      12345
      @UI: {
        lineItem:       [ { position: 35, importance: #LOW } ],
        identification: [ { position: 65, importance: #LOW } ]
           }
      Duration;

7. Activate the metadata extension.

   1. Press Ctrl + F3 to activate the development object.

8. Now open the behavior definition on data model level Z##_R_TRAVEL and use a quick fix to add the new field to the draft table.

   1. Choose the error icon with a light bulb next to the draft table statement.

   2. Choose Recreate draft table z##_travel_d for entity z##_r_travel.

   3. Press Ctrl + F3 to activate the draft table.

9. Return to the behavior definition and add the new view element to the same FIELD statement as the Status view element.

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      123456
      field ( readonly )
      Status,
      Duration,
      ChangedAt,
      ChangedBy,
      LocChangedAt;

10. Use a pragma to suppress the warning Field "DURATION" of entity "Z##_R_TRAVEL" does not have a mapping to table "Z##_TRAVEL". A "mapping" definition should be added..

    Hint

    You find the relevant pragma in the Problem Description of the syntax warning.

    1. In the Problems view, right-click the syntax warning and choose Problem Description.

    2. Adjust the code as follows:

       Code Snippet

       Copy codeSwitch to dark mode

       123
       define behavior for Z##_R_Travel alias Travel
         persistent table z##_travel ##UNMAPPED_FIELD
         draft table z##_travel_d

In your business object, define and implement a determination that calculates the value of the Duration field based on the starting date and end date (suggested name: determineDuration). Make sure that the determination is executed during the save phase and is triggered by changes to either of the two date fields.

Then define a determine action (suggested name: adjustDuration) to trigger the execution of the determination and the validations of the date fields - in case you did the optional part of that exercise. Then define a side effect that is triggered by changes to either of the date fields.

1. In the behavior definition on data model level Z##_R_TRAVEL, define a determination (suggested name: determineDuration) that is executed during save and triggered by a change of the BeginDate element or the EndDate element.

   1. Add the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      1234
      determination determineDuration on save
      { field BeginDate, 
        EndDate;
      }

2. Activate the behavior definition and use a quick fix to add the determination implementation method to the local handler class.

   1. Press Ctrl + F3 to activate the development object.

   2. In the determination statement, place the cursor on the name of the determination and press Ctrl + 1 to invoke the quick assist proposals.

   3. From the list of available quick fixes, choose Add method for determination determineduration of entity z##_r_travel in local class lhc_travel.

3. In the method implementation, use EML in local mode to read the starting date and the end date of all affected travel instances and store the result in an inline declared internal table (suggested name: travels).

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      123456789
      METHOD determineDuration.
      
        READ ENTITIES OF Z##_R_Travel IN LOCAL MODE
          ENTITY Travel
            FIELDS (  BeginDate EndDate )
            WITH CORRESPONDING #( keys )
            RESULT DATA(travels).
      
      ENDMETHOD.

4. Implement a loop over the travels, assigning an inline declared field symbol (suggested name: <travel>). Inside the loop, update the Duration field in the internal table with the difference between EndDate and BeginDate.

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678910111213
      METHOD determineDuration.
      
        READ ENTITIES OF Z##_R_Travel IN LOCAL MODE
          ENTITY Travel
            FIELDS (  BeginDate EndDate )
            WITH CORRESPONDING #( keys )
            RESULT DATA(travels).
      
        LOOP AT travels ASSIGNING FIELD-SYMBOL(<travel>).
          <travel>-Duration = <travel>-EndDate - <travel>-BeginDate.
        ENDLOOP.
      
      ENDMETHOD.

5. After the loop, implement an EML statement in local mode to update the duration for all affected travel instances.

   Hint

   You can use your internal table travels directly after the WITH addition if you place it inside a CORRESPONDING expression.

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678910111213141516171819
      METHOD determineDuration.
      
        READ ENTITIES OF Z##_R_Travel IN LOCAL MODE
          ENTITY Travel
            FIELDS (  BeginDate EndDate )
            WITH CORRESPONDING #( keys )
            RESULT DATA(travels).
      
        LOOP AT travels ASSIGNING FIELD-SYMBOL(<travel>).
          <travel>-Duration = <travel>-EndDate - <travel>-BeginDate.
        ENDLOOP.
      
        MODIFY ENTITIES OF Z##_R_Travel IN LOCAL MODE
          ENTITY Travel
            UPDATE
            FIELDS ( Duration )
            WITH CORRESPONDING #( travels ).
      
      ENDMETHOD.

6. Activate the behavior implementation and return to the behavior definition. Define a determine action (suggested name: adjustDuration) that triggers the execution of the determination and the validations for the date fields.

   If you did not implement validations for the date fields, let the determine action only trigger the determination.

   1. Press Ctrl + F3 to activate the development object.

   2. In the behavior definition, after the definition of the first determine action, add the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678
      determine action adjustDuration
      {
        validation validateBeginDate;
        validation validateEnddate;
        validation validateDateSequence;
      
        determination determineDuration;
      }

7. Define a side effect that executes the determine action adjustDuration after the user changed either of the fields BeginDate or EndDate and specifies field Duration and the messages as targets.

   1. After the definition of the determine action, add the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678
      side effects
      {
        determine action adjustDuration
        executed on field BeginDate,
        field EndDate
        affects field Duration,
            messages;
      }

8. Activate the behavior definition on data model level and edit the behavior definition on projection level. Add the determine action adjustDuration to the projection of the root entity and make the projection reuse the side effects that are defined on data model level.

   1. Press Ctrl + F3 to activate the development object.

   2. In the behavior definition on projection level, adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      1234567891011121314
      projection;
      strict ( 2 );
      
      use draft;
      use side effects;
      
      define behavior for Z##_C_Travel
      use etag
      {
        
      
        use action adjustDuration;
      
      }

9. Activate the behavior projection. Then reload the OData UI service preview and verify that the determine action is executed after you edit the date fields.

   1. Press Ctrl + F3 to activate the development object.

   2. Open the service binding, place the cursor on the root entity and choose Preview....

   3. In the preview, display the details for one of the travels. Change to edit mode and change the value in the Starting Date field.

   4. Press Tab to save the draft and jump to the next input field.

      Result

      The determine action is not yet triggered because there is a second trigger field.

   5. Change the value of the End Date field and press Tab to save the draft and jump to the next input field.

      Result

      Now, the determine action is triggered. If your input is not valid, you see error messages. If your input is valid, the content of the Duration field is updated.