Raising and Handling Business Events

Edit the behavior definition on data model level Z##_R_TRAVEL. In the behavior for the root entity, define an event (suggested name: TravelCreated). Raise the event in an additional save implementation, when one or more new flight travels are created.

1. Edit your behavior definition on data model level Z##_R_TRAVEL and locate the define behavior statement for the root entity Z##_R_Travel.

   1. For example, you can press Ctrl + F to invoke a search dialog where you search for R_Travel.

2. For the root entity, define an event (suggested name: TravelCreated).

   1. Somewhere in the behavior definition, for example after the definition of the cancel_travel action, add the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      1
      event TravelCreated;

3. Enable additional save logic for the root entity.

   1. At the end of the define behavior statement for the root entity, add the with additional save addition as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678910
      define behavior for Z##_R_Travel alias Travel
      persistent table z##_travel
      draft table z##_travel_d
      lock master
      total etag ChangedAt
      authorization master ( instance )
      etag master LocChangedAt
      early numbering
      with additional save
      {

4. Activate the behavior definition.

   1. Press Ctrl + F3 to activate the development object.

5. Navigate to the implementation of the save_modified method.

   Note

   In our case, this method already exists because the travel item behavior contains the with unmanaged save addition. Otherwise, you have to use a quick fix to generate the method and, if necessary, the saver class.

   1. For example, scroll up to the managed implementation in class statement. Place the cursor on zbp_##_r_travel and press F3.

   2. Choose the Local Types tab.

   3. Scroll down to the METHOD save_modified. statement.

6. At the end of the save_modified method implementation, check if there are any new flight travels.

   Hint

   Evaluate the travel component of the create importing parameter.

   1. Before the next ENDMETHOD statement, add the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      123
      IF create-travel IS NOT INITIAL.
      
      ENDIF.

7. If there are newly created flight travels, raise the TravelCreated event, passing the key values from the create-travel parameter.

   Hint

   A CORRESPONDING expression automatically passes the key fields.

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      1234
      IF create-travel IS NOT INITIAL.
        RAISE ENTITY EVENT Z##_R_Travel~TravelCreated
          FROM CORRESPONDING #( create-travel ) .
      ENDIF.

8. Activate the behavior implementation.

   1. Press Ctrl + F3 to activate the development object.

Create a new global class (suggested name: ZCL_##_HANDLER) to handle the TravelCreated event you defined in the previous task. Implement the handler method with a MODIFY ENTITIES statement that uses the business object interface /LRN/437_I_TRAVELLOG to create a log entry for the new flight travels.

1. Create a new global class (suggested name: ZCL_##_HANDLER).

   1. In the Project Explorer, right-click the name of your package ZS4D437_## and choose New→ABAP Class.

   2. In the Name field, enter ZCL_##_HANDLER and in the Description field, enter Handle Business Event TravelCreated.

   3. Choose Next, assign the new development object to a transport request, then choose Finish.

2. Enable the global class to handle events of the root entity of your business object Z##_R_TRAVEL.

   1. Add the FOR EVENTS OF statement, followed by the name of your root entity as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      1234
      CLASS zcl_##_handler DEFINITION
        PUBLIC
        FINAL
        CREATE PUBLIC FOR EVENTS OF Z##_R_Travel.

3. Inside the global class, define a local class (suggested name: lcl_handler) that inherits from the global class CL_ABAP_BEHAVIOR_EVENT_HANDLER. Define a private section in the class.

   Hint

   If you use the lcl code template to insert the local class, remember to remove the PUBLIC SECTION and PROTECTED SECTION statements. They are not allowed in sub classes of CL_ABAP_BEHAVIOR_EVENT_HANDLER.

   1. Navigate to the Local Types tab.

   2. Add the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678910
      CLASS lcl_handler DEFINITION 
        INHERITING FROM cl_abap_behavior_event_handler.
      
        PRIVATE SECTION.
      
      ENDCLASS.
      
      CLASS lcl_handler IMPLEMENTATION.
      
      ENDCLASS.

4. In the local class, define a private method (suggested name: on_travel_created) to handle the TravelCreated event of the root entity.

   Note

   Remember that you need the IMPORTING addition, even though the event does not yet define a parameter.

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678910111213141516
      CLASS lcl_handler DEFINITION 
        INHERITING FROM cl_abap_behavior_event_handler.
      
        PRIVATE SECTION.
          METHODS on_travel_created FOR ENTITY EVENT
            IMPORTING new_travels
              FOR Travel~TravelCreated.
      ENDCLASS.
      
      CLASS lcl_handler IMPLEMENTATION.
      
        METHOD on_travel_created.
      
        ENDMETHOD.
      
      ENDCLASS.

5. At the beginning of the method implementation, declare an internal table (suggested name: log) with the derived type TABLE FOR CREATE /lrn/437_i_travellog.

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      1234
      METHOD on_travel_created.
        DATA log TYPE TABLE FOR CREATE /lrn/437_i_travellog.
      
      ENDMETHOD.

6. Implement a loop over the importing parameter and fill the internal table with the key values of the new flight travels. In addition, fill the Origin component with the name of your own business object Z##_R_TRAVEL.

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      12345678910
      METHOD on_travel_created.
        DATA log TYPE TABLE FOR CREATE /lrn/437_i_travellog.
      
        LOOP AT new_travels ASSIGNING FIELD-SYMBOL(<travel>).
          APPEND VALUE #( AgencyID = <travel>-AgencyId
                          TravelID = <travel>-TravelId
                          Origin   = 'Z##_R_TRAVEL' )
            TO log.
        ENDLOOP.
      ENDMETHOD.

7. After the loop, implement a MODIFY ENTITIES statement that accesses the /LRN/437_I_TRAVELLOG business object interface.

   1. At the end of the method, insert the following code:

      Code Snippet

      Copy codeSwitch to dark mode

      1
      MODIFY ENTITIES OF /LRN/437_I_TravelLog

8. Create new instances of the root entity TravelLog, passing the fields AgencyID, TravelID, and Origin. As input, use the internal table log.

   Note

   When you use EML to create new instances, always populate the %cid field with non-initial values. An alternative is the use of the AUTO FILL CID addition.

   1. Adjust the code as follows:

      Code Snippet

      Copy codeSwitch to dark mode

      12345
      MODIFY ENTITIES OF /LRN/437_I_TravelLog 
        ENTITY TravelLog
          CREATE AUTO FILL CID
          FIELDS ( AgencyID TravelID Origin )
          WITH log.

9. Activate the handler class and test the event handling.

   1. Press Ctrl + F3 to activate the development object.

   2. Reopen the preview of your OData UI service and choose Create to create a new flight travel.

   3. Enter all mandatory fields for the flight travel and choose Create.

   4. Take note of the values displayed in the Agency ID field and the Travel ID field.

   5. Open the preview for OData UI service /LRN/UI_437_TRAVELLOG_O2.

   6. Choose Go. (If there are too many entries, enter Z##_R_TRAVEL under Root Entity Name and choose Go again.)

      Result

      You see an entry that corresponds to the flight travel that you have created.